public class Grid {
  
  public static final int NORTH = 0;
  public static final int EAST = 1;
  public static final int SOUTH = 2;
  public static final int WEST = 3;
  
  private Square[] squares;
  private Psycho[] psychos;
  private int numPsychos;
  private int rows;
  private int cols;
  private int sq_width;
  private int sq_height;
  private int buffX;
  private int buffY;
  private int init_offX;
  private int init_offY;
  private int alphaReduceInc;//on squares
  private Psycho currPsycho;
  private int currSquareIndex;
  
  public Grid(int r, int c, int sq_wid, int sq_hei, int bX, int bY, int init_offsetX, int init_offsetY, int nP, int alphaInc) {
    rows = r;
    cols = c;
    sq_width = sq_wid;
    sq_height = sq_hei;
    buffX = bX;
    buffY = bY;
    init_offX = init_offsetX;
    init_offY = init_offsetY;
    alphaReduceInc = alphaInc;
    squares = new Square[rows*cols];
    makeGrid();
    numPsychos = nP;
    makePsychos();
    currPsycho = psychos[0];
  }
  public void update() {
    for (int i = 0;i<numPsychos;i++) {
      psychos[i].update();
    }
  }
  public void draw() {
    for (int i = 0; i < squares.length;i++) {
      squares[i].draw();
    }
  }
  public void getMove(int squareIndex, Psycho p) {
    if (currSquareIndex == squareIndex) {
      Sequence a = currPsycho.getSequence();
      Sequence b = p.getSequence();
      currPsycho.setSequence(b);
      currPsycho.setRandomColor();
      p.setRandomColor();
      p.setSequence(a);
      squares[squareIndex].setIntersect();
    }
    currPsycho = p;
    currSquareIndex = squareIndex;
  }
  private void makePsychos() {
    psychos = new Psycho[numPsychos];
    //sets pattern to draw
    //sequenceA
    int[] numMovesEachTurnA = {3, 2, (int)random(2),5,3,1, 1};
    boolean[] turnDirecA = {true, false, false, false, true,false,true};//left,right,left
    int wildTurnA = 0;//first turn
    Sequence sequenceA = makeSequence(numMovesEachTurnA, turnDirecA, wildTurnA);
    
    //sequence B
    int[] numMovesEachTurnB = {2, 2, (int)random(2),5,3,1, 1};
    boolean[] turnDirecB = {false, true, true, true, false,true,false};//left,right,left
    int wildTurnB = 0;//first turn
    Sequence sequenceB = makeSequence(numMovesEachTurnB, turnDirecB, wildTurnB);
    
    //sequenceC
    int[] numMovesEachTurnC = {4, 5, (int)random(10),8,6,4,2};
    boolean[] turnDirecC = {false, true, false, false, false,false,false};//left,right,left
    int wildTurnC = 0;//first turn
    Sequence sequenceC = makeSequence(numMovesEachTurnC, turnDirecC, wildTurnC);
    
    //sequenceD
    int[] numMovesEachTurnD = {10, 10, 10,8,6,6,4, 4, 3, 2};
    boolean[] turnDirecD = {false, false, false, false, false,false,false, false, false, false};
    int wildTurnD = 6;//first turn
    Sequence sequenceD = makeSequence(numMovesEachTurnD, turnDirecD, wildTurnD);
    
    //sequenceE
    int[] numMovesEachTurnE = {1,1,1,1,1,1};
    boolean[] turnDirecE = {false, true, false, true, false,true};
    int wildTurnE = 0;
    Sequence sequenceE = makeSequence(numMovesEachTurnE, turnDirecE, wildTurnE);
    
    Sequence[] sequences = new Sequence[5];
    sequences[0] = sequenceA;
    sequences[1] = sequenceB;
    sequences[2] = sequenceC;
    sequences[3] = sequenceD;
    sequences[4] = sequenceE;
    //make psychos
    for (int i = 0;i<numPsychos;i++) {
      color psychoCol = color ((int)random(100)+140, (int)random(100)+140, (int)random(250), 255);
      psychos[i] = new Psycho(((rows*cols)/2)+cols/2, psychoCol, sequences[(int)random(sequences.length)], this, Psycho.STEP_MODE);
      //psychos[i] = new Psycho(((rows*cols)/2)+cols/2, psychoCol, sequences[4], this, Psycho.STEP_MODE);//fixed sequence
      //psychos[i] = new Psycho((int)random(rows*cols), psychoCol, sequences[4], this, Psycho.STEP_MODE);//fixed sequence
    }
  }
  private Sequence makeSequence(int[] n, boolean[] d, int wild) {
    Sequence seq;
    int tot = n.length;
    Turn[] turns = new Turn[tot];
    for (int i = 0;i<tot;i++) {
      turns[i] = new Turn(n[i], d[i]);
    }
    seq = new Sequence(turns, wild);
    return seq;
  }
  private void makeGrid() {
    int count = 0;
    for (int r = 0; r < rows; r++) {
      for (int c = 0; c < cols; c++) {
        squares[count] = new Square(((sq_width+buffX)*c)+init_offX, ((sq_height+buffY)*r)+init_offY, sq_width, sq_height, color(0,0,0,255), color(255,255,255), alphaReduceInc);
        count++;
      }
    }         
  }
  //sent from Psychos
  public void drawPath(Integer[] path, color c) {
    for (int i = 0; i<path.length; i++) {
      int currSquare = path[i].intValue();
      //println("currSquare: " + currSquare);
      squares[currSquare].setColor(c);
    }
  }
  public int getRows() {
    return rows;
  }
  public int getCols() {
    return cols;
  }
  public int move (int currSquareIndex, int direc) {
    if (direc == NORTH) {
      if (currSquareIndex > cols-1) {
        currSquareIndex -= cols;
      } else {
        currSquareIndex=currSquareIndex % cols + (cols*(rows-1));
      }
    } else if (direc == EAST) {
      if ((currSquareIndex % cols) < cols-1) {
        //println("east col: " + currSquareIndex % cols);
        currSquareIndex++;
      } else {
        currSquareIndex-=(cols-1);
      }
    } else if (direc == SOUTH) {
      if (currSquareIndex < cols * (rows-1)) {
        currSquareIndex += cols;
      } else {
        currSquareIndex = currSquareIndex % cols;
      }
    } else if (direc == WEST) {
      if ((currSquareIndex % cols) > 0) {
        currSquareIndex--;
      } else {
        currSquareIndex+=cols-1;
      }
    }
    return currSquareIndex;
  }
  public int setDirection(int compassDirec, boolean left) {
    //println("....");
    //println("compassDirec: " + compassDirec);
    if (left) {
      //println("left");
      if (compassDirec>0) {
        compassDirec--;
      }else {
        compassDirec = 3;
      }
    }else {
      //println("right");
      if (compassDirec<3) {
        compassDirec++;
      }else {
        compassDirec = 0;
      }
    }
    //println("compassDirec: " + compassDirec);
    //println("....");
    return compassDirec;
  }
  
}